//
// BOOK2ADR.VDM                                         C.Z. 12.02.1998
//
// wandelt Netscape-Bookmarks (3.01) in OPERA-Adressen (3.10) um

BoF

// Netscape-Header entfernen

Search("|<<DL>", NOERR)
Del_Line(-7)
Del_Line(1)

// Opera-Header einfügen

IT("Opera Hotlist version 2.0")
IN(2)


// Einträge durchgehen

while(! At_Eof){
  Replace("|W","",NOERR)               // leading spaces löschen

  if(Match("<DT><H3 FOLDED |M>")==0){      // Ordner ?
    Del_Char(Chars_Matched)
    Search("<")                        // hinter Titel
    Del_Block(Cur_Pos, EoL_Pos, RESET+NORESTORE) // Rest löschen
    BoL
          IT("#FOLDER")         IN(1)
    IC(9) IT("NAME=")    EoL    IN(1)
    IC(9) IT("CREATED=0")       IN(1)
    IC(9) IT("VISITED=0 (?)")   IN(1)
    IC(9) IT("ORDER=-1")        IN(1)
  } else {

  if(Match("<DT><A HREF=")==0){        // Lesezeichen ?
    Del_Char(Chars_Matched+1)      // inkl. " löschen
    BB(CLEAR) BB(Cur_Pos)
    Search('"')
    Reg_Copy_Block(11,BB,Cur_Pos, DELETE+RESET)   // URL ausschneiden
    BB(Cur_Pos)
    Search(">", ADVANCE)
    Del_Block(BB,Cur_Pos, RESET+NORESTORE)  // VISIT etc. löschen
    Search("<")                                   // hinter Titel
    Del_Block(Cur_Pos, EoL_Pos, RESET+NORESTORE)  // Rest löschen
    BoL
          IT("#URL")                IN(1)
    IC(9) IT("NAME=")  EoL          IN(1)
    IC(9) IT("URL=")   Reg_Ins(11)  IN(1)   // URL von oben einfügen
    IC(9) IT("CREATED=0")           IN(1)
    IC(9) IT("VISITED=0 (?)")       IN(1)
    IC(9) IT("ORDER=-1")
    Line(1)
    
    if(Match("<DD>")==0){              // folgt Description ?
      IC(9) IT("DESCRIPTION=")
      Del_Char(4)
      Search("|H0D", NOERR)           // <CR> suchen
      while(! Error_Match){
        Char(-4)
        if(Match("<BR>")==0){       // Fortsetzung der Descr. ?
          Del_Char(4+1+2)           // <BR><CR><CR><LF> löschen
        } else {
          Char(4)
          Del_Char(1+2)             // <CR><CR><LF> löschen
          break                     // Descr. ist zu Ende
        }
        Search("|H0D", NOERR)       // sonst weiter suchen
      }
      IN(1)
    }
    IN(1)
  } else {

  if(Match("<DL><p>")==0){             // Einrückung ?
    BoL  Del_Line(1)                   // löschen
  } else {

  if(Match("</DL><p>")==0){            // Einrückung Ende ?
    BoL  Del_Line(1)                   // löschen
    IT("-")   IN(1)                    // und 1 Ebene zurück für Opera
  } else {

  if(Match("<HR>")==0){                // Horizontale Linie ?
    BoL  Del_Line(1)                   // löschen
  } else {
                                       // alles andere
    Line(1)                            // überspringen

  }}}}}

}

BoF

// neuen Dateinamen aufbereiten

Reg_Set(12, PATHNAME)
Reg_Set(13, FILE_EXT)

Buf_Switch(33)
Reg_Ins(12, BEGIN)
Search("|@(13)", NOERR)
if(! Error_Match){
  Del_Block(Cur_Pos, EoL_Pos)
} else {
  EoL
}
IT(".adr")
BoL
Reg_Copy(11,1)

// erzeugte Datei mit neuem Namen speichern

Buf_Switch(1)
File_Save_As(@11, NOMSG)