//
//  CUSTOMIZE.VDM                   Ch.Ziemski 24.10.2002
//                                             17.11.2002
//
//
//  For a Demo look at CUSTDEMO.VDM
//
// 
// in: $103 label to execute here
//     #104 # of calling macro
//     $104 TReg with list of controls

if( ! Is_Win32_Version){
  Get_Key("Sorry, but this macro only runs with the Win32-version of VEDIT!")
  return(-1)
}

if(Reg_Size(103) == 0){                           // if no label: return with error
   return(-1)                                     
}

if((Reg_Compare(103, "READCONFIG") != 0)  && (Reg_Compare(103, "SAVECONFIG") != 0)  && (Reg_Compare(103, "DIALOG")  != 0) && (Reg_Compare(103, "DIALOG+SAVE")  != 0)){ 
  return(-1)                                     // if no correct label: return with error
}
Goto @(103)            // goto the label given as parameter


// --------------------------------------------------------------------

:READCONFIG:

//
// #101 buf for macro
// #102 buf for list
// #103 current buf num
// #104 flag for loaded file
// #105 type of var
// #106 reg# of var
       
//Reg_Empty(103)                            // prepare for commands

#103=Buf_Num
Buf_Switch(#101=Buf_Free(EXTRA))

if(#101 == -1){
  Dialog_Input_1(103,"`ERROR`, 
  `No more buffers!`", 
  APP+CENTER,0,0) 
  return(1)
}

Reg_Ins(#104)                             // insert running macro

#102=Buf_Switch(Buf_Free(EXTRA))
Reg_Ins(104)                              // the control list
Replace("|<|[|W]|N","", BEGIN+ALL+NOERR)  // remove empty lines
Replace("|<|[|W]","", BEGIN+ALL+NOERR)    // remove leading whitespace
BoF

while(! At_EoF){
  if(Cur_Char != 35 && Cur_Char != 36){
    Line(1, NOERR+ERRBREAK)
    continue
  }
  #105 = Cur_Char                    // type of register
  Char(1)

  #106=Num_Eval(SUPPRESS+ADVANCE)    // number of register


  Reg_Copy_Block(104, Cur_Pos, Cur_Pos + 1)      // get divider
  Char(1)

  // get name of variable
  Match("|*|@(104)")
  #104=Chars_Matched
  Reg_Copy_Block(106, Cur_Pos, Cur_Pos + #104 -1)

  if(Reg_Size(106)==0){
    Line(1, NOERR+ERRBREAK)
    continue
  }

  // search variable in macro
  Buf_Switch(#101)
  Reg_Empty(105)
  if (Search("|<//|[|w]|@(106):|[|w]",BEGIN+ADVANCE+NOERR)) {
    Reg_Copy_Block(105, Cur_Pos, EOL_Pos)
  }

  // if found: set it
  if(Reg_Size(105) == 0){   // get default
    Buf_Switch(#102)           // back to the control list
    Char(#104)
    Reg_Copy_Block(105, Cur_Pos, EoL_Pos)
  }

  if(#105 == 35){                  // #
    #@106=Num_Eval_Reg(105)
  }else{                          // $
    Reg_Set(#106, @105)
  }
  //Out_Reg(103, APPEND) Type_Newline(1) Out_Reg(CLEAR)
  
  Buf_Switch(#102)           // back to the control list
  Line(1, NOERR+ERRBREAK)
}

Buf_Switch(#101) Buf_Quit(OK)
Buf_Switch(#102) Buf_Quit(OK)
Buf_Switch(#103)

return(0)

//--------------------------------------------------------------------------

:DIALOG+SAVE:

Reg_Push(104,104, SET)    // save the register with the control list (without emptying it)
Num_Push(104,104)         // and the number of the calling macro

Call("DIALOG")

if(Return_Value != 0){    // if cancelled or not successful
  Num_Pop(104,104)        //   restore registers 
  Reg_Pop(104,104)        //   and return
  return
}

Num_Pop(104,104)          // restore registers
Reg_Pop(104,104)     

  
// and then go on with saving:
// Goto SAVECONFIG

//--------------------------------------------------------------------------

:SAVECONFIG:

//
// #101 buf for macro
// #102 buf for list
// #103 current buf num
// #104 flag for loaded file
// #105 type of var
// #106 reg# of var
// #119 ret for DI_1()
       

#103=Buf_Num
Buf_Switch(#101=Buf_Free(EXTRA))

if(#101 == -1){
  Dialog_Input_1(103,"`ERROR`, 
  `No more buffers!`", 
  APP+CENTER,0,0) 
  return(1)
}

Reg_Ins(#104)                             // insert running macro

// Get macro's filename

if (Search("|<//|[|w]MYNAME:|[|w]",BEGIN+ADVANCE+NOERR)) {
  Reg_Copy_Block(106, Cur_Pos, EOL_Pos)
}else{                                 // if not found: can't save it => return
  Buf_Quit(OK)
  Buf_Switch(#103)
  return(1)
}


// Try to find the source file of this running macro so we can save the
// user's selection back into it.

Reg_Empty(105)

if (File_Exist('"|@(106)"')) {
  Reg_Set(105, CUR_DIR)
} else {
  if (File_Exist('"|(USERMACRO)/|@(106)"')) {
    Reg_Set(105, USERMACRO)
  } else {
    if (File_Exist('"|(MACRO)/|@(106)"')) {
      Reg_Set(105, MACRO)
    }
  }
}

if(Reg_Size(105) > 0){                  // if macro source file found

  Reg_Set(105, "\", APPEND)             // complete the path with filename
  Reg_Set(105, @106, APPEND)

  if((#104=File_Check('"|@(105)"')) != -1){    // if is already open in a buffer show warning message
    #119=Dialog_Input_1(106,"`Attention!`,
    `.gThe new configuration is active for this macro call but wasn't saved because the source file`,
    `of the running macro (|@(106)) seems to be already loaded.`,
    ` `,
    `Should the loaded macro been modified to reflect the changes?`,
    `\(Note: You have to save the file manually then to make the changes active for the next macro calls!)`,
    `[&Yes]`, `[&No]`",APP+CENTER,0,0)
    if(#119 != 1){
      Buf_Quit(OK)
      Buf_Switch(#103)
      return(1)
    }
    Buf_Switch(#104)                    // switch to the already loaded macro file
    Save_Pos()
  }else{                                // else switch to the temp. buffer with the macro text
    Buf_Switch(#101)
    Buf_Empty(OK)
    File_Open(@105, FORCE)              // and load the macro file there
  }
  
  
  #102=Buf_Switch(Buf_Free(EXTRA))
  Reg_Ins(104)                              // load the control list
  Replace("|<|[|W]|N","", BEGIN+ALL+NOERR)  // remove empty lines
  Replace("|<|[|W]","", BEGIN+ALL+NOERR)    // remove leading whitespace
  BoF

  while(! At_EoF){                          // work through the list
    if(Cur_Char != 35 && Cur_Char != 36){
      Line(1, NOERR+ERRBREAK)
      continue
    }
    #105 = Cur_Char                          // type of register

    Char(1)

    #106=Num_Eval(SUPPRESS+ADVANCE)          // number of register

    Reg_Copy_Block(119, Cur_Pos, Cur_Pos + 1)      // get divider  //NEW

    // get name of variable
    Char(1)
    Match("|*|@(119)")                                           //NEW
    Reg_Copy_Block(106, Cur_Pos, Cur_Pos + Chars_Matched -1)     //NEW
    //OLD Reg_Copy_Block(106, Cur_Pos, EoL_Pos)

    if(Reg_Size(106)==0){
      Line(1, NOERR+ERRBREAK)
      continue
    }

    // search variable in macro
    if(#104 == -1){                     // if macro was loaded into temp. buffer
      Buf_Switch(#101)
    }else{
      Buf_Switch(#104)                  // if macro file was already loaded
    }
      
    if (Search("|<//|[|w]|@(106):|[|w]",BEGIN+ADVANCE+NOERR)) {           // if found: set it
      if(#105 == 35){                 // #
        Del_Block(Cur_Pos, EOL_Pos)   // Delete the old entry
        Num_Ins(#@106, LEFT+NOCR)     // Insert new one
      }else{                          // $
        Del_Block(Cur_Pos, EOL_Pos)   // Delete the old entry
        Reg_Ins(#106)                 // Insert the user's value
      }
    }
    Buf_Switch(#102)                   // back to the control list
    Line(1, NOERR+ERRBREAK)
  }

  if(#104 == -1){                     // if macro was loaded into temp. buffer
    Buf_Switch(#101)
    File_Save(OK+NOMSG)               // Save user's values into source macro
  }else{
    Buf_Switch(#104)                  // if macro file was already loaded
    Restore_Pos()
  }

  Buf_Switch(#102)
  Buf_Quit(OK)                        // close buffer with list

}

Buf_Switch(#101) Buf_Quit(OK)          // close temp. buffer with macro text
Buf_Switch(#103)                       // Switch back to original buffer
Update()

return(0)

//---------------------------------------------------------------------------

:DIALOG:

//
// #101 buf for macro
// #102 buf for list
// #103 current buf num
// #104 offset for DI_1()
// #119 chars_matched
//
// $103 variable text for DI_1()
// $104 set-macro for DI_1()
// $105 set-macro for the end
//
// ....


#103=Buf_Num
Buf_Switch(#101=Buf_Free(EXTRA))

if(#101 == -1){
  Dialog_Input_1(103,"`ERROR`, 
  `No more buffers!`", 
  APP+CENTER,0,0) 
  return(1)
}


Reg_Ins(#104)                             // insert running macro

// Get macro's filename

if (Search("|<//|[|w]MYNAME:|[|w]",BEGIN+ADVANCE+NOERR)) {
  Reg_Copy_Block(106, Cur_Pos, EOL_Pos)
}else{                                 // if not found: return
  Buf_Quit(OK)
  Buf_Switch(#103)
  return(1)
}

// Beginning of the TReg for DI_1()

Reg_Set(103, "`Customization of ")
Reg_Set(103, @106, APPEND)
Reg_Set(103, "`,
`Here you are able to change configuration of the macro.`,
`The changes are stored in the macro itself for future use.`,
", APPEND)


#102=Buf_Switch(Buf_Free(EXTRA))
Reg_Ins(104)                              // the control list
Replace("|<|[|W]|N","", BEGIN+ALL+NOERR)  // remove empty lines
Replace("|<|[|W]","", BEGIN+ALL+NOERR)    // remove leading whitespace
BoF

Line(5, NOERR)
if(!EM){
  Del_Line(ALL)     // Only 5 lines allowed (=input boxes in DI_1())
}

BoF

Reg_Empty(104)
Reg_Empty(105)

#104=80              // Offset for registers to use with DI_1()

while(! At_EoF){
  if(Cur_Char != 35 && Cur_Char != 36){
    Line(1, NOERR+ERRBREAK)
    continue
  }

  #105 = Cur_Char                    // type of register
  Char(1)

  #106=Num_Eval(SUPPRESS+ADVANCE)    // number of register


  Reg_Copy_Block(119, Cur_Pos, Cur_Pos + 1)      // get divider
  Char(1)

  // get name of variable
  Match("|*|@(119)")
  #119=Chars_Matched
  Reg_Copy_Block(106, Cur_Pos, Cur_Pos + #119 -1)

  if(Reg_Size(106)==0){
    Line(1, NOERR+ERRBREAK)
    continue
  }

  // search variable in macro
  Buf_Switch(#101)

  if (Search("|<//|[|w]|@(106):|[|w]",BEGIN+ADVANCE+NOERR)) {  // if found: use it

    #104++     // offset for variables to use
    
    // Create "Set-Macros" for DI_1() and later

    Reg_Set(104, " Reg_Set(", APPEND)
    Num_Str(#104, 104, LEFT+APPEND)
    
    if(#105 == 35){                  // #
      Reg_Set(104, ', "', APPEND)
      Num_Str(#@106, 104, LEFT+APPEND)
      Reg_Set(104, '")', APPEND)

      Reg_Set(105, " Reg_Set(104, ' #", APPEND)
      Num_Str(#106, 105, LEFT+APPEND)
      Reg_Set(105, "=', APPEND) ", APPEND)
                                                     // cut all not numeric trailing characters, or so...
      Reg_Set(105, "Num_Str(Num_Eval_Reg(", APPEND)
      Num_Str(#104, 105, LEFT+APPEND)
      Reg_Set(105, "), ", APPEND)
      Num_Str(#104, 105, LEFT+APPEND)
      Reg_Set(105, ") ", APPEND)
      
      Reg_Set(105, "Reg_Set(104, @", APPEND)
      Num_Str(#104, 105, LEFT+APPEND)
      Reg_Set(105, ", APPEND)", APPEND)

    }else{                          // $
      Reg_Set(104, ', "', APPEND)
      Reg_Set(104, @#106, APPEND)
      Reg_Set(104, '")', APPEND)

      Reg_Set(105, " Reg_Set(104, ' Reg_Set(", APPEND)
      Num_Str(#106, 105, LEFT+APPEND)
      Reg_Set(105, ", `', APPEND) ", APPEND)
      Reg_Set(105, "Reg_Set(104, @", APPEND)
      Num_Str(#104, 105, LEFT+APPEND)
      Reg_Set(105, ", APPEND) ", APPEND)
      Reg_Set(105, "Reg_Set(104, '`) ', APPEND)", APPEND)
    }
    Out_Reg(104, APPEND) Type_Newline(1) Out_Reg(CLEAR)
    Out_Reg(105, APPEND) Type_Newline(1) Out_Reg(CLEAR)

    // get comment
    Buf_Switch(#102)           // back to the control list
    Char(#119)
    if(!At_EoL){
      Reg_Copy_Block(106, Cur_Pos, EoL_Pos)
    }

    Reg_Set(103, "`??", APPEND)
    Reg_Set(103, @106, APPEND)
    Reg_Set(103, "    `, 
", APPEND)     // use varname or comment

  }
  Buf_Switch(#102)           // back to the control list
  Line(1, NOERR+ERRBREAK)
}

Num_Push(81,85)   //  for DI_1() 
Reg_Push(81,85)   //    "

Call(104)     // set registers for DI_1()

#104=Dialog_Input_1(81,"|@(103)
`[&OK]`,`[&Cancel]`",SET+APP+CENTER,0,0)

Reg_Empty(104)
Call(105)     // set registers from DI_1()  (set TReg104)

Reg_Pop(81,85)
Num_Pop(81,85)

if(#104 == 1){
  Call(104)     // set registers from DI_1()
}


Buf_Switch(#101) Buf_Quit(OK)
Buf_Switch(#102) Buf_Quit(OK)
Buf_Switch(#103)


if(#104 == 1){
  return(0)
}else{
  return(1)
}
//=======================================================================