//
//   Dialog_Input_1()       Big example                    Ch. Ziemski    09.09.2001
//

// Easy to test with this key assignment:
// F12    [MENU]ba[T-REG COPY][OPTION]R100[OPTION]O[MENU]me[OPTION]R100[OPTION]O
// 
// So you can edit this text/macro and immediately execute it via F12


// some text variables used in DI_1():
Reg_Set(80, "second input")
Reg_Set(81, "horizontal placed checkboxes")
Reg_Set(82, "Checkbox2")
Reg_Set(83, "Button &x")


// text register and numeric register 91 is the starting point for DI_1(1)

Reg_Set(91, "first")     // 1st input box
Reg_Set(92, "second")    // 2nd input box

#91=1                    // Checkbox1 checked  (0 = unchecked)
#92=0x80                 // Checkbox2 greyed out, unchecked  (0x81 = greyed + checked)
#93=0x100                // Checkbox3 hidden

#94=3                    // 1st radio group: 3.rd radio button is selected   //  in doco: 0x04  (bit2) ?!?!?!
#95=1                    // 2nd radio group: 1.st radio button is selected
              
#77=Dialog_Input_1(91,"
'Title',
'Lines at the top of the window \ttabbed space \nSecond line',
'??First Input',
'??|@(80):',
'|@(81)',
'[]Checkbox&1',
'.h[]|@(82)',
'.h[]Checkbox3',
'[OK]',
'[|@(83)]',
'First radio group, without modifier',
'()Radio-G1-1',
'()Radio-G1-2',
'()Radio-G1-3',
'Next radio group, grouped with .g and centered with .c',
'.g.c()Radio-G2-1',
'()Radio-G2-2',
'()Radio-G2-3',
'[Cancel]',
'[Button4]',
'[Button5]'",
SET+APP+CENTER,110,110)    // SET to fill in default input(s), always should be set from VEDIT+ 6.0 upwards


//----------- Results: --------------------

Message("Key#   = ")    Num_Type(#77)              // # of pressed key
Message("Input1 = ")    Reg_Type(91)               // first input box
Message("\nInput2 = ")  Reg_Type(92)               // second input box

Message("\nCheckboxes: ")
Num_Type(#91, LEFT+NOCR) NT(#92, NOCR) NT(#93, NOCR)    // values of the checkboxes

Message("      Radiobuttons: ")
Num_Type(#94, LEFT+NOCR) #95          // values of the radio button groups