//
//   MAILS.VDM                       C.Z.   20.08.1997
//                                          03.09.2000   for VEDIT 5.20
//                                          02.09.2004
//
//   Reformats the headers of emails (in UNIX-Format) to be more readable
//   (by deleting some lines etc.)
//
//   It's no longer correct UNIX-Format then!
//
// To do:
//    - buffer usage
//    - register usage
// 
//=======================================================================

#103=Buf_Num
#104=Buf_Free
#105=0


Config( U_E_UNDO, "Enable undo Ins_Newline Command mode", 0 )

Begin_Of_File
#105=0

while(! At_EOF){
  Block_Begin(CLEAR)
  Search("|<From |M@|M |F|F|F |F|F|F |D|D |D|D:|D|D:|D|D", CASE+NOERR)
  if(Error_Match){
    Begin_Of_File
    // Update
    Out_Reg(12)
    Num_Type(#105, NOCR)
    Out_Reg(CLEAR)
    // DI1(1,"Mail-Aufbereitung;;;|@(12) Mails bearbeitet.",SUPPRESS)

    Dialog_Input_1(1,"`Mail-Aufbereitung`,
    `|@(12) Mails bearbeitet.`")

    Buf_Switch(#104)
    Buf_Quit(DELETE+OK)
    Buf_Switch(#103)
    Return
  }
  #105=#105+1               // counter for mails
  Block_Begin(Cur_Pos)
  Search("|L|L")
  Block_End(Cur_Pos)
  Reg_Copy_Block(10,Block_Begin,Block_End)      // header of current mail

  Buf_Switch(#104)
  // Update
  Buf_Empty(OK)
  Reg_Ins(10)        // header of current mail
  Reg_Empty(20) 
  Reg_Empty(21) 
  Reg_Empty(22) 
  Reg_Empty(23)

  Begin_Of_File

  while(! At_EOF){
    if(Match("From ",ALL)==0){
      RegCopy(20,1)
    } else {
      if(Match("From:",ALL)==0){
        // DOV("\NW\")
        Search("|!|X")
        Ins_Text("   ")
        Begin_Of_Line
        RegCopy(21,1)
      } else {
        if(Match("Date: ",ALL)==0){
          // DOV("\NW\")
          Search("|!|X")
          Ins_Text("   ")
          Begin_Of_Line
          RegCopy(22,1)
        } else {
          if(Match("Subject:",ALL)==0){
            RegCopy(23,1)
          }
        }
      }
    }
    Del_Line(1)
  }
  Reg_Ins(21)

  // if Date: is missing
 
  if(Reg_Size(22)==0){
    Reg_Ins(20,BEGIN)
    Block_Begin(Cur_Pos)
    Search(" ",COUNT+ADVANCE,2)
    // DOV("\ME\BED")
    Del_Block(Block_Begin,Block_End)
    Begin_Of_Line
    Ins_Text("Date:    ")
    End_Of_Line
    Line(1)
  } else {
    Reg_Ins(22)
  }
  Reg_Ins(23)
  Reg_Copy_Block(11, 0, File_Size)

  Buf_Switch(#103)
  Del_Block(Block_Begin, Block_End)
  Ins_Text("=====================================================================")
  Ins_NewLine(1)
  Reg_Ins(11)                         // re-insert short header
  Ins_Text("=====================================================================")
}