//
//   MAILS2.VDM                      C.Z.   20.08.1997
//                                          03.09.2000   for VEDIT 5.20
//                                          04.09.2004
//
//   Reformats the headers of emails (in UNIX-Format)
//
//   Does some checks (currently: for missing Date:)
//
//
//=======================================================================

Reg_Empty(103)
Reg_Empty(104)
Reg_Empty(105)   // temp. for display etc.
Reg_Empty(106)   // temp. for display etc.

#105=0           // counter for mails
#106=0           // counter for fixed mails


Config( U_E_UNDO, "Enable undo Ins_Newline Command mode", 0 )

Begin_Of_File

while(! At_EOF){
  Block_Begin(CLEAR)
  Search("|<From |*@|* |F|F|F |F|F|F |D|D |D|D:|D|D:|D|D", CASE+NOERR)
  if(Error_Match){
    Begin_Of_File
    // Update
    Num_Str(#105, 105)
    Num_Str(#106, 106)

    Dialog_Input_1(103,"`Mail-Checker`,
    `|@(105) mail(s) checked`,
    `|@(106) mail(s) fixed`")

    Return
  }
  
  #105=#105+1               // counter for mails
  Block_Begin(Cur_Pos)
  Search("|L|L")
  Block_End(Cur_Pos)

  Search_Block("|<From ", Block_Begin, Block_End, BEGIN)
  Reg_Copy(105,1)

  Search_Block("|<Date: ", Block_Begin, Block_End, BEGIN+NOERR)
  // if Date: is missing
  //
  // From name@server.domain Sat Feb 17 22:25:00 1996
  // Date: Sat, 17 Feb 96 22:25 +0100

  if (Error_Match) {
    #106++               // counter for fixed mails
    Search_Block("|<From: ", Block_Begin, Block_End, BEGIN)
    Line(1, NOERR)
    // Ins_Text("X-Mail-Check: fixed")
    // Ins_Newline(1)
    Reg_Ins(105, BEGIN)    // From
    //        From nam@sd   Sat   Feb   17   22:25:00 1996
    Replace("^From +.*@.* +{.+} +{.+} +{.+} +{.+} +{[0-9]+} *{.*}$","Date: \1, \3 \2 \5 \4 \6", REGEXP+MAX)
  }

  Search("|<From |*@|* |F|F|F |F|F|F |D|D |D|D:|D|D:|D|D", CASE+NOERR)
  #100=Cur_Pos
  if (! Error_Match) {
    Goto_Pos(Block_End)
    // Replace_Block("^{F}rom ","\t\1rom ", Cur_Pos, #100, ALL+NOERR+REGEXP)      // BUG !!!
    Replace_Block("|<From ","|TFrom ", Cur_Pos, #100, ALL+NOERR+CASE)
    Goto_Pos(Block_End)
    Replace_Block("|<from ","|Tfrom ", Cur_Pos, #100, ALL+NOERR+CASE)
    Goto_Pos(Block_End)
    Replace_Block("|<FROM ","|TFROM ", Cur_Pos, #100, ALL+NOERR+CASE)
    // while (Cur_Pos <= #100) {
    //   Search("|<|{F,f}rom ", NOERR)
    //   if (! Error_Match) {
    //     Ins_Char(9)
    //   }
    //   Line(1, NOERR)
    // }
  } else {                       // up to EoF
    Goto_Pos(Block_End)
    // Replace("^{F}rom ","\t\1rom ", ALL+NOERR+REGEXP)       // BUG !!!
    Replace("|<From ","|TFrom ", ALL+NOERR+CASE)
    Goto_Pos(Block_End)
    Replace("|<from ","|Tfrom ", ALL+NOERR+CASE)
    Goto_Pos(Block_End)
    Replace("|<FROM ","|TFROM ", ALL+NOERR+CASE)
  }
  Goto_Pos(#100)
}