//
// ORA-SQL-Reformat.vdm                   19.09.2007
//

//    HEIGHT     BLOCKS NAME                           PARTITION_NAME                    LF_ROWS    LF_BLKS LF_ROWS_LEN LF_BLK_LEN    BR_ROWS    BR_BLKS BR_ROWS_LEN BR_BLK_LEN DEL_LF_ROWS DEL_LF_ROWS_LEN DISTINCT_KEYS MOST_REPEATED_KEY BTREE_SPACE USED_SPACE   PCT_USED ROWS_PER_KEY BLKS_GETS_PER_ACCESS   PRE_ROWS PRE_ROWS_LEN OPT_CMPR_COUNT OPT_CMPR_PCTSAVE
//---------- ---------- ------------------------------ ------------------------------ ---------- ---------- ----------- ---------- ---------- ---------- ----------- ---------- ----------- --------------- ------------- ----------------- ----------- ---------- ---------- ------------ -------------------- ---------- ------------ -------------- ----------------
//         4    1535681 IBINVALUES~SEL                                                 106631836    1459243  5971382816       7852    1459242      12107    49383173       8028     2333464       130673984     106631836                 1  1.1555E+10 6020765989         53            1                    5          0            0              2                0

// HEIGHT                  --                 4
// BLOCKS                  --           1535681
// NAME                    --    IBINVALUES~SEL
// PARTITION_NAME          --                  
// LF_ROWS                 --         106631836
// LF_BLKS                 --           1459243
// LF_ROWS_LEN             --        5971382816
// LF_BLK_LEN              --              7852
// BR_ROWS                 --           1459242
// BR_BLKS                 --             12107
// BR_ROWS_LEN             --          49383173


// goto_line("----"
BoL
if (Match("---") != 0){
  return
}
#60=Cur_Line
EoF
#65=Cur_Line
Goto_Line(#60)

while (! At_EoL){
  #61=Cur_Col
  Search("|X")
  #62=Cur_Col
  Line(-1)
  Goto_Col(#61)
  RCB(103, Cur_Pos, Cur_Pos+#62-#61)
  Line(2)
  Goto_Col(#61)
  RCB(104, Cur_Pos, Cur_Pos+#62-#61)
  EoF

  Reg_Ins(103)
  BoL
  Replace("|[|W]","")
  EoL
  Search("|!|W", REVERSE+ADVANCE+NOERR)
  Del_Block(Cur_Pos, Eol_Pos)  
  Ins_Text(" -- ")

  #103=CP
  Reg_Ins(104)
  #104=CP
  Search_Block("|!|W", Cur_Pos, #103, REVERSE+ADVANCE+NOERR)
  Del_Block(CP,#104)
  GP(#103)
  Replace("|[|W]","")
  EoL
  Ins_Newline(1)
  Goto_Line(#60)
  Goto_Col(#62)
  if (At_EoL) {
    break
  }
  Search("|!|X")
}

Goto_Line(#65)
#66=0
#68=0

while(! At_EOL){
  Search_Block(" --", Cur_Pos, EoL_Pos, ADVANCE+ERRBREAK)
  #67=Cur_Col
  if (#67 > #66) {
    #66=#67
  }
  Char(3)
  #69=EoL_Pos - Cur_Pos
  if (#69 > #68) {
    #68=#69
  }
  Line(1, ERRBREAK)
}

Goto_Line(#65)
while(! At_EOL){
  Search_Block("--", Cur_Pos, EoL_Pos, ERRBREAK)
  #69=EoL_Pos - Cur_Pos
  Ins_Indent(#66+1)
  Search_Block("--", Cur_Pos, EoL_Pos, ADVANCE+ERRBREAK)
  Ins_Char(32, COUNT,#68-#69)
  Line(1, ERRBREAK)
}