//
// von Scott Lambert  2/2000
//
// overlay with a string at a prespecified column for x number of lines

// text register 10 hold the overlay string
// numeric register 10 holds starting line - default current line
// numeric register 11 holds column number - default current column
// numeric register 12 holds repeat for # number of lines - default 1
// numeric register 13 holds overwrite / insert flag - default overwrite

// 0=overwrite  1=insert

Config( W_WORD_WRAP, "Enable word wrap & formatting (*)", 0 ) // turn off wordwrap
#13=0                                   // default to overwrite
#32=0					// set blank line flag to 0 or no


// get user input

get_input(10,"Enter text string : ",nocr)
#10=get_num("Starting Line # : ")
#11=get_num("Column # : ")
#12=get_num("Repeat # : ")
#13=get_num("0:Overwrite, 1:Insert ? : ")

if(reg_size(10)==0) {breakout_extra} 	// if t-reg 10 contains no text abort macro
if(#10==0) {#10=cur_line}              // if no input default to current line
if(#11==0) {#11=cur_col}               // if no input default to current column
if(#12==0) {#12=1}                      // do minimum 1 times
if(#13<>1) {#13=0}                      // if not insert then default to overwrite

reg_empty(30)                           // empty t-reg 30
for(#33=1;#33<#11;#33++) {              // for loop
reg_set(30," ",append)                  // create padding for blank lines 
}                                       // end of for loop
reg_set(30,@10,append)                  // add t_reg 10


#30=#10					// set starting line position
 
for(#31=1;#31<=#12;#31++) {		// for #12 times do ....
goto_line(#30)                          // goto line in #30
match("|<|[|W]|L")                      // are we on a blank line ?
if(return_value==0) {	                // if yes, do ...
ins_text(@30)                           // insert t-reg 30
#30=#10+#31                             // increment line position by 1
continue                                // skip to end of for loop
}
goto_col(#11)                           // goto column in #11

if(#13==0) {				// if overwrite, do ...
reg_ins(10,overwrite)			// overwrite text with contents of t-reg 10
} else {				// else insert is choosen, so do...
reg_ins(10)                             // insert contents of t-reg 10
}					// end of else

#30=#10+#31                             // increment line position by 1
}					// end of for loop

goto_line(#10)                          // return to starting line #
goto_col(#11)                           // at column position
update()				// update screen - end of code