//
//   SAP-SU10-Abgleich.vdm                         Ch. Ziemski    18.12.2003
//

BoF

#90=Buf_Num     // SU10 Liste
#91=#90+1       // Mail-Liste aus Lotus Notes

#92=Buf_Free    // Ergebnis

Line(3)

while (!At_EoF) {

  Reg_Empty(98) // flag
  
  Buf_Switch(#90)
  Char(3)  // Username
  
  if (Cur_Char == 45) {   // "-"
    break
  }
  
  #103=Cur_Pos
  Search("||")
  Char(-1)
  Search("|! ", REVERSE+ADVANCE)
  Char(1)
  Reg_Copy_Block(103, #103, Cur_Pos)   // Username

  Goto_Col(99)
  #103=Cur_Pos
  Goto_Col(179)
  Search("|! ", REVERSE+ADVANCE)
  Reg_Copy_Block(104, #103, Cur_Pos)   // Vollst. Name

  Goto_Col(445)
  #103=Cur_Pos
  Search(" ")
  Reg_Copy_Block(105, #103, Cur_Pos)   // Ort

  Buf_Switch(#91)
  Search("|<|[@]|@(103)|W", BEGIN+NOERR)
  if (EM) {
    Buf_Switch(#92)
    if (Reg_Size(105) == 0) {
      Ins_Text("Extern/CPIC/RFC:    ")
    } else {
      Ins_Text("Fehlt in LN-Liste:  ")
    }
    Reg_Ins(103)
    Ins_Newline(1)
  } else {
    if (Cur_Char == 64) {
      Reg_Set(98, "@")
    }
    Goto_Col(93)    // Vollst. Name
    Search("|! ")
    if (Match(@104) != 0) {
      #103=Cur_Pos
      Goto_Col(138)
      Search("|! ", REVERSE+ADVANCE)
      Reg_Copy_Block(106, #103, Cur_Pos)   // Vollst. Name
      Buf_Switch(#92)
      Reg_Ins(98)
      Ins_Text("Name stimmt nicht:  ")
      Reg_Ins(103)
      Ins_Indent(40)
      Reg_Ins(104)
      Ins_Indent(70)
      Ins_Text(" <> ")
      Reg_Ins(106)
      Ins_Newline(1)
    } else {
      Goto_Col(138)    // Firma
      #99=0   // flag
      Reg_Copy_Block(106, Cur_Pos, EoL_Pos)  
      if (Match("TKS-ES BO") == 0) {
        if (Reg_Compare(105, "BOCHUM") != 0) {
          #99=1
        }
      } else {
      if (Match("TKS-ES GE") == 0) {
        if (Reg_Compare(105, "GELSENKIRCHEN") != 0) {
          #99=1
        }
      
      } else {
      if (Match("TKS-ES IS") == 0) {
        if (Reg_Compare(105, "ISBERGUES") != 0) {
          #99=1
        }
      
      } else {
      if (Match("SFG GmbH") == 0) {
        if (Reg_Compare(105, "BOCHUM") != 0) {
          #99=1
        }
      }}}} 

      if (#99 == 1) {
        Buf_Switch(#92)
        Reg_Ins(98)
        Ins_Text("Firma stimmt nicht: ")
        Reg_Ins(103)
        Ins_Indent(40)
        Reg_Ins(105)
        Ins_Indent(70)
        Ins_Text(" <> ")
        Reg_Ins(106)
        Ins_Newline(1)
      } 
      
      Buf_Switch(#91)
      BoL
      Goto_Col(25)
      If (Match(" ") == 0) {
        Buf_Switch(#92)
        Reg_Ins(98)
        Ins_Text("keine Mail in LN:   ")
        Reg_Ins(103)
        Ins_Newline(1)
      }
    }
  }
  Buf_Switch(#90)
  Line(1, NOERR)
}
BoF
Buf_Switch(#92)
Sort(0, FileSize)
BoF