//
//  SAP-SU10.VDM                                       C.Z. 28.02.2003
//                                                          04.03.2003
//  Überträgt eine solche Namens-Liste:
//
//  ACHILLES
//  ALBRECHT
//  # Kommentar
//  OTTO
//
//  in 21er-Gruppen (ohne Kommentar- und Leerzeilen) und übergibt sie an das ClipBoard.
//  Dieses kann dann in R/3 SU10 eingefügt werden.
//

Reg_Set(103, `
WinActivate,  Benutzerpflege: Einstieg Massenänderungen
WinWaitActive, Benutzerpflege: Einstieg Massenänderungen

SEND, ^+/
SEND, +{TAB}
SEND, {DOWN}
SEND, {DOWN}
SEND, #{CTRLDOWN}#v#{CTRLUP}#
                                                        
Send, {PGDN}
`)
Reg_Save(103, "|(VEDIT_TEMP)\sap-su10.|(PID)", OK)
Reg_Empty(103)


#13=0         // automatic = off
#15=0         // line counter
Reg_Empty(90)

while (! At_EoF) {

  BoL
  while ((Match("|[|W]|N") == 0) || (Match("|[|W]#") ==0)) {
    Line(1, NOERR)
  }
  
  if (! At_EoF) {
    Reg_Copy(90, 1, APPEND)
    #15++
  }

  Line(1, NOERR)

  if (At_EoF || (#15 > 20)) {
    Buf_Switch(Buf_Free)
    Reg_Ins(90)
    BoF
    Clip_Copy_Block(0, Filesize)
    Buf_Quit(OK)
    Update

    if (#13 == 0) {
      Num_Str(#15, 92)
      #12=Dialog_Input_1(11,"`Action required`, 
      `|@(92) lines are copied to clipboard`,
      `Please switch to SAP and insert clipboard. Then come back ...`,
      `[&Next]`,`[&Automatic]`,`[&Cancel]`",SET+APP+CENTER,0,0)

      if (#12 == 0 || #12 == 3) { break }
      if (#12 == 2 ) {
        #13=1     // Auto on
        System('c:\programme\autoit\autoit.exe "|(VEDIT_TEMP)\sap-su10.|(PID)" ', DOS+SIMPLE)
      }
    } else {
      System('c:\programme\autoit\autoit.exe "|(VEDIT_TEMP)\sap-su10.|(PID)" ', DOS+SIMPLE)
    }

    #15=0         // line counter
    Reg_Empty(90)
  }
}


File_Delete("|(VEDIT_TEMP)\sap-su10.|(PID)", OK)