//
// SETMARKER.VDM                      Christian Ziemski      28.05.1999
//                                                           15.08.2000  f. 5.20 DI1
//
//
// Displays the used Text Markers with line number and text example
//
// Input of a marker number set that marker to the actual cursor position,
//
//
// (For the Windows version of VEDIT only!)
//

// Build the list of used markers

Out_Reg(103)
M("  No.       Line     Text\n----------------------------------------------------------------------\n")
for(#103=0;#103<10;#103++){
  if(Marker(#103)!=-1){
    NT(#103,NOCR)                           // marker no.
    M(" : ") 
    Save_Pos()
    GP(Marker(#103))
    NT(Cur_Line(),FORCE+NOCR)               // cursor line of marker position
    M(" :  ") 
    #104=EoL_Pos
    Restore_Pos()
    if((Marker(#103)+20)<#104){             // text example max. to EoL
      #104=Marker(#103)+20
    }
    Type_Block(Marker(#103),#104)
    Type_Newline()
  }
}
Out_Reg(CLEAR)

// Show the Input Dialog

Reg_Empty(104)
DI1(104,"'Set Text Marker','Set marker no. (0-9)','??|@(103)'",SCREEN+CENTER,0,0) 
#104=BN
#103=Buf_Free(EXTRA)
if(#103==-1){                        // no more extra buffer?
  Alert()
  BS(#104)
  return
}

// set the selected marker

if(Reg_Size(104)>0){                 // user input?
  BS(#103)
  RI(104,BEGIN)
  #103=Num_Eval()                    // evaluate marker no.
  BQ(OK)
  BS(#104)
  if(Chars_Matched>0){               // numeric input?
    if(#103>=0 && #103<10){          // valid?
      Set_Marker(#103, Cur_Pos)
    }
  }
}